import org.puremvc.as3.patterns.facade.∗;
  
  import com.me.myapp.model.*;
  import com.me.myapp.view.*;
  import com.me.myapp.controller.*;
  
  public class MyFacade extends Facade
  {
   // Notification constants. The Facade is the ideal
   // location for these constants, since any part
   // of the application participating in PureMVC 
   // Observer Notification will know the Facade.
   public static const GO_COMMAND:String = "go";
    
   // Override Singleton Factory method 
   public static function getInstance() : MyFacade {
    if (instance == null) instance = new MyFacade();
    return instance as MyFacade;
   }
    
   // optional initialization hook for Facade
   override public function initializeFacade() : void {
    super.initializeFacade();
    // do any special subclass initialization here
   }
  
   // optional initialization hook for Controller
   override public function initializeController() : void {
    // call super to use the PureMVC Controller Singleton. 
    super.initializeController();
  
    // Otherwise, if you're implmenting your own
    // IController, then instead do:
    // if ( controller != null ) return;
    // controller = MyAppController.getInstance();
    
    // do any special subclass initialization here
    // such as registering Commands
    registerCommand( GO_COMMAND, com.me.myapp.controller.GoCommand )
   }
  
   // optional initialization hook for Model
   override public function initializeModel() : void {
    // call super to use the PureMVC Model Singleton. 
    super.initializeModel();
  
    // Otherwise, if you're implmenting your own
    // IModel, then instead do:
    // if ( model != null ) return;
    // model = MyAppModel.getInstance();
    
    // do any special subclass initialization here
    // such as creating and registering Model proxys
    // that don't require a facade reference at
    // construction time, such as fixed type lists
    // that never need to send Notifications.
    regsiterProxy( new USStateNamesProxy() );
     
    // CAREFUL: Can't reference Facade instance in constructor 
    // of new Proxys from here, since this step is part of
    // Facade construction!  Usually, Proxys needing to send 
    // notifications are registered elsewhere in the app 
    // for this reason.
   }
  
   // optional initialization hook for View
   override public function initializeView() : void {
    // call super to use the PureMVC View Singleton. 
    super.initializeView();
  
    // Otherwise, if you're implmenting your own
    // IView, then instead do:
    // if ( view != null ) return;
    // view = MyAppView.getInstance();
    
    // do any special subclass initialization here
    // such as creating and registering Mediators
    // that do not need a Facade reference at construction
    // time.
    registerMediator( new LoginMediator() ); 
  
    // CAREFUL: Can't reference Facade instance in constructor 
    // of new Mediators from here, since this is a step
    // in Facade construction! Usually, all Mediators need 
    // receive notifications, and are registered elsewhere in 
    // the app for this reason.
   }
  }